update

2026-01-31 00:48:41 +03:00 · 2024-09-03 09:34:33 +08:00
parent 27f34aa3e8
commit 585146181b
5147 changed files with 1734881 additions and 0 deletions
--- a/deps/OpenCSG/CMakeLists.txt.in
+++ b/deps/OpenCSG/CMakeLists.txt.in
@@ -0,0 +1,101 @@
+cmake_minimum_required(VERSION 3.0)
+
+project(OpenCSG)
+
+if (NOT BUILD_SHARED_LIBS)
+  set(GLEW_USE_STATIC_LIBS ON)
+elseif (MSVC)
+  set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON)
+endif()
+
+find_package(OpenGL REQUIRED)
+
+set(GLEW_VERBOSE ON)
+find_package(GLEW 1.13.0 REQUIRED)
+
+set(_srcfiles 
+    src/area.cpp
+    src/batch.cpp
+    src/context.cpp
+    src/channelManager.cpp
+    src/frameBufferObject.cpp
+    src/frameBufferObjectExt.cpp
+    src/occlusionQuery.cpp
+    src/opencsgRender.cpp
+    src/openglHelper.cpp
+    src/pBufferTexture.cpp
+    src/primitive.cpp
+    src/primitiveHelper.cpp
+    src/renderGoldfeather.cpp
+    src/renderSCS.cpp
+    src/scissorMemo.cpp
+    src/settings.cpp
+    src/stencilManager.cpp
+    RenderTexture/RenderTexture.cpp
+    include/opencsg.h
+    src/opencsgConfig.h
+    src/area.h
+    src/batch.h
+    src/context.h
+    src/channelManager.h
+    src/frameBufferObject.h
+    src/frameBufferObjectExt.h
+    src/occlusionQuery.h
+    src/offscreenBuffer.h
+    src/opencsgRender.h
+    src/openglHelper.h
+    src/pBufferTexture.h
+    src/primitiveHelper.h
+    src/scissorMemo.h
+    src/settings.h
+    src/stencilManager.h
+)
+
+add_library(opencsg ${_srcfiles})
+target_include_directories(opencsg PUBLIC $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>)
+target_include_directories(opencsg PUBLIC $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>)
+target_link_libraries(opencsg PRIVATE GLEW::GLEW OpenGL::GL)
+
+include(CMakePackageConfigHelpers)
+
+include(GNUInstallDirs)
+
+write_basic_package_version_file(
+    "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"     
+    VERSION 1.4.2
+    COMPATIBILITY AnyNewerVersion
+)
+
+install(TARGETS opencsg 
+  EXPORT ${PROJECT_NAME}Targets
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} 
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+
+export(EXPORT ${PROJECT_NAME}Targets 
+       FILE "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake" 
+       NAMESPACE ${PROJECT_NAME}:: )
+
+set(ConfigPackageLocation ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
+
+install(EXPORT ${PROJECT_NAME}Targets
+  FILE
+    "${PROJECT_NAME}Config.cmake"
+  NAMESPACE
+    ${PROJECT_NAME}::
+  DESTINATION
+    ${ConfigPackageLocation}
+)
+install(
+    FILES
+      ${PROJECT_SOURCE_DIR}/include/opencsg.h 
+    DESTINATION
+      ${CMAKE_INSTALL_INCLUDEDIR}/opencsg
+)
+install(
+    FILES
+      "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
+    DESTINATION
+      ${ConfigPackageLocation}
+)
--- a/deps/OpenCSG/OpenCSG.cmake
+++ b/deps/OpenCSG/OpenCSG.cmake
@@ -0,0 +1,17 @@
+
+qidistudio_add_cmake_project(OpenCSG
+    # GIT_REPOSITORY https://github.com/floriankirsch/OpenCSG.git
+    # GIT_TAG 83e274457b46c9ad11a4ee599203250b1618f3b9 #v1.4.2
+    URL https://github.com/floriankirsch/OpenCSG/archive/refs/tags/opencsg-1-4-2-release.zip
+    URL_HASH SHA256=51afe0db79af8386e2027d56d685177135581e0ee82ade9d7f2caff8deab5ec5
+    PATCH_COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt.in ./CMakeLists.txt
+    DEPENDS dep_GLEW
+)
+
+if (TARGET ${ZLIB_PKG})
+    add_dependencies(dep_OpenCSG ${ZLIB_PKG})
+endif()
+
+if (MSVC)
+    add_debug_dep(dep_OpenCSG)
+endif ()